easyspider - Version1 - contrib - Webserver - SOURCE CODE

# /usr/bin/perl -Imodules
# file: web_fork.pl
# Figure 14.3: A forking web server

use strict;
use IO::Socket;
use IO::File;
use IO::Select;
use Daemon;
use Web;

use constant PIDFILE => 'web_fork.pid';

my $DONE = 0;
$SIG{INT}  = $SIG{TERM} = sub { $DONE++ };

my $port = shift || 80;
my $socket = IO::Socket::INET->new( LocalPort => $port,
                                    Listen    => SOMAXCONN,
                                    Reuse     => 1 ) or die "Can't create listen socket: $!";
my $IN = IO::Select->new($socket);

# create PID file, initialize logging, and go into the background
init_server(PIDFILE);

warn "Listening for connections on port $port\n";

# accept loop
while (!$DONE) {
  next unless $IN->can_read;
  next unless my $c = $socket->accept;
  my $child = launch_child();
  unless ($child) {
    close $socket;
    handle_connection($c);
    exit 0;
  }
  close $c;
}

warn "Normal termination\n";

# /usr/bin/perl -Imodules
# web_prefork2.pl
# Figure 14.5: This preforking server serializes accept() and
#              relaunches new children to replace old ones

use strict;
use IO::Socket;
use IO::File;
use Fcntl ':flock';
use Daemon;
use Web;

use constant PREFORK_CHILDREN  => 5;
use constant MAX_REQUEST       => 30;
use constant PIDFILE           => "prefork.pid";
use constant DEBUG             => 1;

my $CHILD_COUNT = 0;   # number of children
my $DONE        = 0;   # set flag to true when server done

$SIG{INT}  = $SIG{TERM} = sub { $DONE++ };

my $port = shift || 80;
my $socket = IO::Socket::INET->new( LocalPort => $port,
                                    Listen    => SOMAXCONN,
                                    Reuse     => 1 ) or die "Can't create listen socket: $!";

# create PID file, initialize logging, and go into background
init_server(PIDFILE);

while (!$DONE) {
  make_new_child() while $CHILD_COUNT < PREFORK_CHILDREN;
  sleep;         # wait for a signal
}

kill_children();
warn "normal termination\n" if DEBUG;
exit 0;

sub make_new_child {
  my $child = launch_child(\&cleanup_child);
  if ($child) {  # child > 0, so we're the parent
    warn "launching child $child\n" if DEBUG;
    $CHILD_COUNT++;
  } else {
    do_child($socket);      # child handles incoming connections
    exit 0;                 # child is done
  }
}


... [truncated, 21 more lines] ...