bitjoe - Contrib - Sortierung - SOURCE CODE

# Sort::Array.pm
#
# Copyright (c) 2001 Michael Diekmann <michael.diekmann@undef.de>. All rights
# reserved. This program is free software; you can redistribute it and/or
# modify it under the same terms as Perl itself.

# Documentation could be found at the bottom or use (after install):
# > perldoc Sort::Array

package Sort::Array;

require 5.003_03;
require Exporter;

use strict;
use vars qw(@EXPORT_OK @ISA $VERSION $error);
@ISA = qw(Exporter);

# we export nothing by default :)
@EXPORT_OK = qw(
	Sort_Table
	Discard_Duplicates
);

$VERSION = '0.26';

#///////////////////////////////////////////////////////////////////////#
#									#
#///////////////////////////////////////////////////////////////////////#

sub Discard_Duplicates {
	# Get the args and put them into a Hash.
    	my (%arg) = @_;
	$error = 0;

	# Check for content that should be sorted,
	# else return error-code.
	if (scalar(@{$arg{data}}) == 0) {
		$error = 104;
		return undef;
	}

	my $use_warn = 0;
	# Turn warnings off, because we do first a '<=>' and if that
	# fails, we do a 'cmp'. And then a warning comes up.
	# After working, we turn $^W to the same as before.
	if ($^W) {
		$use_warn = $^W;
		$^W = 0;
	}

... [truncated, 489 more lines] ...

use ExtUtils::MakeMaker;
# See lib/ExtUtils/MakeMaker.pm for details of how to influence
# the contents of the Makefile that is written.

eval { require 5.003_03 }
	or die <<EOL;
# This Module requires lvaluable subroutines, which are not avaiable
# in the version of Perl earlier than 5.6.0. Please upgrade!
EOL

WriteMakefile (
	'NAME'		=> 'Sort::Array',
	'VERSION_FROM'	=> 'Array.pm', # finds $VERSION
);

NAME
    Sort::Array - This extended sorting algorithm allows you to

    a) sort an array by ANY field number, not only the first. b) find
    duplicates in your data-set and sort them out.

    The function is case-sensitive. Future versions might come without this
    limitation.

SYNOPSIS
      use Sort::Array qw(
          Sort_Table
          Discard_Duplicates
      );
      @data = Sort_Table(
          cols      => '4',
          field     => '4',
          sorting   => 'descending',
          structure => 'csv',
          separator => '\*',
          data      => \@data,
      );
      @languages = Discard_Duplicates(
          sorting      => 'ascending',
          empty_fields => 'delete',
          data         => \@languages,
      );

DESCRIPTION
    Sort_Table() is capable of sorting table-form arrays by a particular
    value.

    Discard_Duplicates() discards doubles from an array and returns the
    sorted array.

  Usage

      @data = Sort_Table(
          cols      => '4',
          field     => '4',
          sorting   => 'descending',
          structure => 'csv',
          separator => '\*',
          data      => \@data,
      );

      @languages = Discard_Duplicates(
          sorting      => 'ascending',
          empty_fields => 'delete',
          data         => \@languages,

... [truncated, 210 more lines] ...

# Before `make install' is performed this script should be runnable with
# `make test'. After `make install' it should work as `perl test.pl'

######################### We start with some black magic to print on failure.

# Change 1..1 below to 1..last_test_to_print .
# (It may become useful if the test is moved to ./t subdirectory.)

BEGIN { $| = 1; print "1..1\n"; }
END {print "not ok 1\n" unless $loaded;}
use Sort::Array;
$loaded = 1;
print "ok 1\n";

######################### End of black magic.

# Insert your test code below (better if it prints "ok 13"
# (correspondingly "not ok 13") depending on the success of chunk 13
# of the test code):